home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Floppyshop 2
/
Floppyshop - 2.zip
/
Floppyshop - 2.iso
/
art&graf.ix
/
art-3485
/
art-5571
/
cartile.pov
< prev
next >
Wrap
Text File
|
1994-08-10
|
2KB
|
89 lines
// Car tile picture for SIS
// render size: 96x72
#include "colors.inc"
camera {
location <0, 0, -9>
direction <0, 0, 3.8>
up <0, 1, 0>
right <4/3, 0, 0>
look_at <0, 0, 2.5>
}
#declare Tyre = difference {
cylinder { <0, 0, 0>, <1, 0, 0>, 1.4 }
cone {
<.5, 0, 0>, 1
<1.1, 0, 0>, 1.3
}
}
#declare Car = union {
difference { // Car body
box { <-1, 0, -2>, <1, 1, 2> }
cylinder { <-1.1, 5.2, -1.5>, <1.1, 5.2, -1.5>, 5 }
pigment {
bozo
scale <.25, .25, .5>
color_map {
[0 color Green]
[1 color red .7 green .5 blue .3]
}
quick_color Green
}
}
union { // Tyres
object { Tyre scale .4 translate <1, 0, -.9> }
object { Tyre scale .4 translate <1, 0, .9> }
object { Tyre scale .4 rotate 180*y translate <-1, 0, -.9> }
object { Tyre scale .4 rotate 180*y translate <-1, 0, .9> }
pigment { Gray30 }
finish { phong 1 phong_size 10 }
}
sphere { // Windshield
<0, 0, 0>, 1
scale <.8, .2, 1.2>
rotate -20*x
translate 0.5*y
pigment { color blue .1 }
finish { phong 1 reflection .2 }
}
union { // Lights
box { <-.95, .05, -2.05>, <-.65, .15, -2> }
box { <.65, .05, -2.05>, <.95, .15, -2> }
pigment { Yellow }
finish { ambient .5 }
}
union {
box { <-.95, .2, 2>, <-.8, .8, 2.05> }
box { <.8, .2, 2>, <.95, .8, 2.05> }
pigment { Red }
finish { ambient .5 }
}
bounded_by { box { <-1.42, -.58, -2.07>, <1.42, 1.02, 2.07> } }
}
light_source { <.5, 8, 4> color White }
light_source { <4, 3, -8> color White }
object {
Car
scale .5
rotate <-20, 47, 0>
translate <0, -.2, 1.08>
}
plane {
z, 10
pigment {
bozo
scale .2
color_map {
[0 color Yellow]
[1 color Red]
}
}
finish { ambient 1 diffuse 0 }
}